Java中字符串拼接的一些細節(jié)分析

2019-11-26 15:18:52

字體：大中小

供稿：網(wǎng)友

工作日忙于項目的邏輯實現(xiàn)，周六有點時間，從書柜里拿出厚厚的英文版Thinking In Java，讀到了字符串對象的拼接。參考著這本書做個翻譯，加上自己思考的東西，寫上這篇文章記錄一下。

不可變的String對象

在Java中,String對象是不可變的(Immutable)。在代碼中，可以創(chuàng)建多個某一個String對象的別名。但是這些別名都是的引用是相同的。
比如s1和s2都是”droidyue.com”對象的別名，別名保存著到真實對象的引用。所以s1 = s2

復(fù)制代碼代碼如下:

String s1 = "droidyue.com";
String s2 = s1;
System.out.println("s1 and s2 has the same reference =" + (s1 == s2));

Java中僅有的重載運算符

在Java中，唯一被重載的運算符就是字符串的拼接相關(guān)的。+,+=。除此之外，Java設(shè)計者不允許重載其他的運算符。

拼接剖析

真的有性能代價么

了解了上面兩點，可能會有這樣的思考，既然Sting對象不可變，那么多個（三個及以上）字符串拼接必然產(chǎn)生多余的中間String對象。

復(fù)制代碼代碼如下:

String userName = "Andy";
String age = "24";
String job = "Developer";
String info = userName + age + job;

要得到上面的info，就會userName和age拼接生成臨時一個String對象t1,內(nèi)容為Andy24，然后有t1和job拼接生成最終我們需要的info對象，這其中，產(chǎn)生了一個中間的t1，而且t1創(chuàng)建之后，沒有主動回收，勢必會占一定的空間。如果是一個很多(假設(shè)上百個，多見于對對象的toString的調(diào)用)字符串的拼接，那么代價就更大了，性能一下會降低很多。

編譯器的優(yōu)化處理

真的會有上面的性能代價么，字符串拼接這么常用，沒有特殊的處理優(yōu)化么，答案是有的，這個優(yōu)化進行在編譯器編譯.java到bytecode時。

一個Java程序如果想運行起來，需要經(jīng)過兩個時期，編譯時和運行時。在編譯時，Java 編譯器(Compiler)將java文件轉(zhuǎn)換成字節(jié)碼。在運行時，Java虛擬機（JVM）運行編譯時生成的字節(jié)碼。通過這樣兩個時期，Java做到了所謂的一處編譯，處處運行。

我們實驗一下編譯期都做了哪些優(yōu)化，我們制造一段可能會出現(xiàn)性能代價的代碼。

復(fù)制代碼代碼如下:

public class Concatenation {
  public static void main(String[] args) {
      String userName = "Andy";
      String age = "24";
      String job = "Developer";
      String info = userName + age + job;
      System.out.println(info);
  }
}

對Concatenation.java進行編譯一下。得到Concatenation.class

復(fù)制代碼代碼如下:

javac Concatenation.java

然后我們使用javap反編譯一下編譯出來的Concatenation.class文件。javap -c Concatenation。如果沒有找到j(luò)avap命令，請考慮將javap所在目錄加入環(huán)境變量或者使用javap的完整路徑。

復(fù)制代碼代碼如下:

17:22:04-androidyue~/workspace_adt/strings/src$ javap -c Concatenation
Compiled from "Concatenation.java"
public class Concatenation {
public Concatenation();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

public static void main(java.lang.String[]);
    Code:
       0: ldc           #2                  // String Andy
       2: astore_1
       3: ldc           #3                  // String 24
       5: astore_2
       6: ldc           #4                  // String Developer
       8: astore_3
       9: new           #5                  // class java/lang/StringBuilder
      12: dup
      13: invokespecial #6                  // Method java/lang/StringBuilder."<init>":()V
      16: aload_1
      17: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      20: aload_2
      21: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      24: aload_3
      25: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      28: invokevirtual #8                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      31: astore        4
      33: getstatic     #9                  // Field java/lang/System.out:Ljava/io/PrintStream;
      36: aload         4
      38: invokevirtual #10                 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
      41: return
}

其中，ldc，astore等為java字節(jié)碼的指令，類似匯編指令。后面的注釋使用了Java相關(guān)的內(nèi)容進行了說明。我們可以看到上面有很多StringBuilder,但是我們在Java代碼里并沒有顯示地調(diào)用，這就是Java編譯器做的優(yōu)化，當(dāng)Java編譯器遇到字符串拼接的時候，會創(chuàng)建一個StringBuilder對象，后面的拼接，實際上是調(diào)用StringBuilder對象的append方法。這樣就不會有我們上面擔(dān)心的問題了。

僅靠編譯器優(yōu)化？

既然編譯器幫我們做了優(yōu)化，是不是僅僅依靠編譯器的優(yōu)化就夠了呢，當(dāng)然不是。
下面我們看一段未優(yōu)化性能較低的代碼

復(fù)制代碼代碼如下:

public void  implicitUseStringBuilder(String[] values) {
  String result = "";
  for (int i = 0 ; i < values.length; i ++) {
      result += values[i];
  }
  System.out.println(result);
}

使用javac編譯，使用javap查看

復(fù)制代碼代碼如下:

public void implicitUseStringBuilder(java.lang.String[]);
    Code:
       0: ldc           #11                 // String 
       2: astore_2
       3: iconst_0
       4: istore_3
       5: iload_3
       6: aload_1
       7: arraylength
       8: if_icmpge     38
      11: new           #5                  // class java/lang/StringBuilder
      14: dup
      15: invokespecial #6                  // Method java/lang/StringBuilder."<init>":()V
      18: aload_2
      19: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      22: aload_1
      23: iload_3
      24: aaload
      25: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      28: invokevirtual #8                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      31: astore_2
      32: iinc          3, 1
      35: goto          5
      38: getstatic     #9                  // Field java/lang/System.out:Ljava/io/PrintStream;
      41: aload_2
      42: invokevirtual #10                 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
      45: return

其中8: if_icmpge 38 和35: goto 5構(gòu)成了一個循環(huán)。8: if_icmpge 38的意思是如果JVM操作數(shù)棧的整數(shù)對比大于等于（i < values.length的相反結(jié)果）成立，則跳到第38行（System.out）。35: goto 5則表示直接跳到第5行。

但是這里面有一個很重要的就是StringBuilder對象創(chuàng)建發(fā)生在循環(huán)之間，也就是意味著有多少次循環(huán)會創(chuàng)建多少個StringBuilder對象，這樣明顯不好。赤裸裸地低水平代碼啊。

稍微優(yōu)化一下，瞬間提升逼格。

復(fù)制代碼代碼如下:

public void explicitUseStringBuider(String[] values) {
  StringBuilder result = new StringBuilder();
  for (int i = 0; i < values.length; i ++) {
      result.append(values[i]);
  }
}

對應(yīng)的編譯后的信息

復(fù)制代碼代碼如下:

public void explicitUseStringBuider(java.lang.String[]);
    Code:
       0: new           #5                  // class java/lang/StringBuilder
       3: dup
       4: invokespecial #6                  // Method java/lang/StringBuilder."<init>":()V
       7: astore_2
       8: iconst_0
       9: istore_3
      10: iload_3
      11: aload_1
      12: arraylength
      13: if_icmpge     30
      16: aload_2
      17: aload_1
      18: iload_3
      19: aaload
      20: invokevirtual #7                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      23: pop
      24: iinc          3, 1
      27: goto          10
      30: return