在寫從梅兒小屋的友情鏈接數(shù)據(jù)庫轉(zhuǎn)換為CuteLink V1.0的時候用到了好些Access的表和字段的操作，好些不會，查閱了資料后使用通過，現(xiàn)整理如下：

建表：
Sql="CREATE TABLE webtype ("&_
 "id AutoIncrement,"&_
 "hits smallint NOT NULL,"&_
 "name nvarchar (12) NOT NULL,"&_
 "PRIMARY KEY (id))"
Conn.Execute(Sql)

其中，AutoIncrement 為自動編號數(shù)據(jù)類型，PRIMARY KEY 為主鍵。

刪除索引：
Conn.execute("DROP INDEX id on link;")

添加索引：
Conn.execute("Create Unique Index iusername on link(username);")

添加一個username主鍵
Conn.execute("Alter Table Link Add username nvarchar(12) null PRIMARY KEY")

以下為動網(wǎng)V7.0升級文件中的一些通用函數(shù)，很實用：

'刪除字段通用函數(shù)
Sub DelColumn(TableName,ColumnName)
 On Error Resume Next
 Conn.Execute("Alter Table "&TableName&" Drop "&ColumnName&"")
 If Err Then
  Response.Write TableTop & "刪除 "&TableName&" 表中字段<font color=blue>錯誤</font>，請手動將數(shù)據(jù)庫中 <B>"&ColumnName&"</B> 字段刪除，原因" & Err.Description & "<BR>" & TableEnd
  Err.Clear
  Response.Flush
 Else
  Response.Write TableTop & "刪除 "&TableName&" 表中字段 "&ColumnName&" 成功 <BR>" & TableEnd
  Response.Flush
 End If
End Sub

'添加字段通用函數(shù)
Sub AddColumn(TableName,ColumnName,ColumnType)
 On Error Resume Next
 Conn.Execute("Alter Table "&TableName&" Add "&ColumnName&" "&ColumnType&"")
 If Err Then
  Response.Write TableTop & "新建 "&TableName&" 表中字段<font color=blue>錯誤</font>，請手動將數(shù)據(jù)庫中 <B>"&ColumnName&"</B> 字段建立，屬性為 <B>"&ColumnType&"</B>，原因" & Err.Description & "<BR>" & TableEnd
  Err.Clear
  Response.Flush
 Else
  Response.Write TableTop & "新建 "&TableName&" 表中字段 "&ColumnName&" 成功 <BR>" & TableEnd
  Response.Flush
 End If
End Sub

'更改字段通用函數(shù)
Sub ModColumn(TableName,ColumnName,ColumnType)
 On Error Resume Next
 Conn.Execute("Alter Table "&TableName&" Alter Column "&ColumnName&" "&ColumnType&"")
 If Err Then
  Response.Write TableTop & "更改 "&TableName&" 表中字段屬性<font color=blue>錯誤</font>，請手動將數(shù)據(jù)庫中 <B>"&ColumnName&"</B> 字段更改為 <B>"&ColumnType&"</B> 屬性，原因" & Err.Description & "<BR>" & TableEnd
  Err.Clear
  Response.Flush
 Else
  Response.Write TableTop & "更改 "&TableName&" 表中字段屬性 "&ColumnName&" 成功 <BR>" & TableEnd
  Response.Flush
 End If
End Sub

以下是使用方法：

AddColumn "link","username","nvarchar(12) not null"
DelColumn "link","img"
ModColumn "link","username","nvarchar(12) not null PRIMARY KEY"