--創(chuàng)建測(cè)試數(shù)據(jù)庫(kù)
CREATE DATABASE Db
GO
--對(duì)數(shù)據(jù)庫(kù)進(jìn)行備份
BACKUP DATABASE Db TO DISK='c:/db.bak' WITH FORMAT
GO
--創(chuàng)建測(cè)試表
CREATE TABLE Db.dbo.TB_test(ID int)
--延時(shí)1秒鐘,再進(jìn)行后面的操作(這是由于SQL Server的時(shí)間精度最大為百分之三秒,不延時(shí)的話,可能會(huì)導(dǎo)致還原到時(shí)間點(diǎn)的操作失敗)
WAITFOR DELAY '00:00:01'
GO
--假設(shè)我們現(xiàn)在誤操作刪除了 Db.dbo.TB_test 這個(gè)表
DROP TABLE Db.dbo.TB_test
--保存刪除表的時(shí)間
SELECT dt=GETDATE() INTO #
GO
--在刪除操作后,發(fā)現(xiàn)不應(yīng)該刪除表 Db.dbo.TB_test
--下面演示了如何恢復(fù)這個(gè)誤刪除的表 Db.dbo.TB_test
--首先,備份事務(wù)日志(使用事務(wù)日志才能還原到指定的時(shí)間點(diǎn))
BACKUP LOG Db TO DISK='c:/db_log.bak' WITH FORMAT
GO
--接下來(lái),我們要先還原完全備份(還原日志必須在還原完全備份的基礎(chǔ)上進(jìn)行)
RESTORE DATABASE Db FROM DISK='c:/db.bak' WITH REPLACE,NORECOVERY
GO
--將事務(wù)日志還原到刪除操作前（這里的時(shí)間對(duì)應(yīng)上面的刪除時(shí)間，并比刪除時(shí)間略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM # --獲取比表被刪除的時(shí)間略早的時(shí)間
RESTORE LOG Db FROM DISK='c:/db_log.bak' WITH RECOVERY,STOPAT=@dt
GO
--查詢一下,看表是否恢復(fù)
SELECT * FROM Db.dbo.TB_test
/*--結(jié)果:
ID
-----------
（所影響的行數(shù)為 0 行）
--*/
--測(cè)試成功
GO
--最后刪除我們做的測(cè)試環(huán)境
DROP DATABASE Db
DROP TABLE #
