Excel 中的 TEXT 函數
TEXT
將數值轉換為按指定數字格式表示的文本。

語法
TEXT(value,format_text)

Value 為數值、計算結果為數字值的公式，或對包含數字值的單元格的引用。
Format_text 為“單元格格式”對話框中“數字”選項卡上“分類”框中的文本形式的數字格式。

說明

Format_text 不能包含星號 (*)。
通過“格式”菜單調用“單元格”命令，然后在“數字”選項卡上設置單元格的格式，只會更改單元格的格式而不會影響其中的數值。使用函數 TEXT 可以將數值轉換為帶格式的文本，而其結果將不再作為數字參與計算。

A B
1 銷售人員 銷售
2 Buchanan 2800
3 Dodsworth 40%
公式 說明（結果）
=A2&" sold "&TEXT(B2, "$0.00")&" worth of units." 將上面內容合并為一個短語 (Buchanan sold $2800.00 worth of units.)
=A3&" sold "&TEXT(B3,"0%")&" of the total sales." 將上面內容合并為一個短語 (Dodsworth sold 40% of the total sales.)

TEXT生成的三種日期格式：
e:
=text(now(),"e") 與 =text(now(),"YYYY") 是一樣的
b
=text(now(),"b") 佛歷2位年份
bbbb
=text(now(),"bbbb") 佛歷4位年份 與公元紀年相差543年也就是公元紀年＋543就是了。
dbnum1
=TEXT(NOW(),"[dbnum1]yyyy年m月d日") 中文小寫日期
dbnum2
=TEXT(NOW(),"[dbnum2]yyyy年m月d日") 中文大寫日期

佛歷為部分佛教國家計算紀元的方式，該計算方式以釋迦摩尼去世當年度為計算基準。
西元1950年，錫蘭首都可倫坡舉辦首屆“世界佛教徒友誼會”，會中議決：佛陀誕生于西元前623年，成道于西元前588年，去世于西元元前543年。三年后的1954年，該年會于緬甸仰光舉行，會中再決議佛教國家以“佛歷”紀元，并以釋迦牟尼涅盤日推算，西元1954年為佛歷2498年。

日期轉換
把20080808修改成2008－08－08的格式可以用以下公式：
=--text("20080808","#-00-00")

把英文月份化成數字月份：
=MONTH(--("Aug"&1))
=MONTH(--("August"&1))

返回一個月的最后一天，就是用下一個月的第一天－1就行。
得到上一個月的最后一天：
=today()-day(now())

確定季度：
=text(roundup(month(now())/3,0),"[dbnum1]第0季度")

星期：
=weekday(now())
=mod(today()-2,7)+1
=text(today(),"aaaa")

返回最近星期天的日期
=today()-weekday(today(),2)
=today()-mod(today()-1,7)
=today()+8-weekday(today())
=today()+6-mod(today()-2,7)

兩個日期相隔的星期天數：
=int((weekday(date1,2)+date2-date1)/7)

轉帖]TEXT 函數運用終極篇(小爪)
轉自http://hi.baidu.com/huanhuanxiao ... 2f3d1663279890.html
2008-06-18 18:58

1.關于 TEXT(102,"!r0c00") 此類格式函數
TEXT(102,"!r0c00") --->"r1c02"
前面加個indirect
indirect(TEXT(102,"!r0c00"),)---->INDIRECT("r1c02",)-->就是等于行1列2 即B1的值
故展開=INDIRECT(TEXT(1002,"!r00c00"),)--->B10的值
=INDIRECT(TEXT(1002,"!r00c0"),)--->B100的值
=INDIRECT(TEXT(102,"!r00c0"),)------->B10的值 注意前后的變化

繼續擴展:
=INDIRECT(TEXT({101;102;103;201;202;203;301;302;303},"!r0c00"),)------->
=INDIRECT({"r1c01";"r1c02";"r1c03";"r2c01";"r2c02";"r2c03";"r3c01";"r3c02";"r3c03"},)這個得到一個數組

題外話:
SMALL(ROW($A$1:$C$3)*100+COLUMN($A$1:$C$3),ROW(1:9))--可得到(張貼:只是為了學習這個方法)------------------------------->{101;102;103;201;202;203;301;302;303}

2.關于此類TEXT({10;1;11;2;13;14;15;8;7;3},"[<=8]#;1")此類格式函數
先了解一下: TEXT({10;1;11;2;13;14;15;8;7;3},"[<=8]#;1")引申出結果為
{"1";"1";"1";"2";"1";"1";"1";"8";"7";"3"},意思就是說大于8的為1,小于等于8的為原來值
看 =TEXT({10;1;11;2;13;14;15;8;7;3},"[>=8]#;1")如果修改成大于等于 引申出結果為
{"10";"1";"11";"1";"13";"14";"15";"8";"1";"1"}

這樣就大家都明白了
繼續展開
=TEXT({10;1;11;2;13;14;15;8;7;3},"[=8]#;1")--->={"1";"1";"1";"1";"1";"1";"1";"8";"1";"1"}
=TEXT({10;1;11;2;13;14;15;8;7;3},"[<>8]#;1")--->={"10";"1";"11";"2";"13";"14";"15";"1";"7";"3"}
=TEXT({10;1;11;2;13;14;15;8;7;3},"[<>""]#;1")-->={"10";"1";"11";"2";"13";"14";"15";"8";"7";"3"}
這樣就大家就更明白

題外話:(相關的例子)
"[<="&LEN($A$6)&"]#;1"--->如果LEN($A$6) 等于8 那么 就可以得到 "[<=8]#;1"
ROW($1:$10)-1----->就可以得到 {0;1;2;3;4;5;6;7;8;9}這個數組
10-ROW($1:$10)--->就可以得到 {9;8;7;6;5;4;3;2;1;0}這個數組

這2個數組有什么用呢?繼續

例1
{"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*10^({9;8;7;6;5;4;3;2;1;0})--->
{"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*{1000000000;100000000;10000000;1000000;100000;10000;1000;100;10;1}--->可以得到下面的值 ={1000000000;100000000;10000000;1000000;100000;10000;3000;900;80;7} 加個sum 可以得到1111113987

例2.
={"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*10^({0;1;2;3;4;5;6;7;8;9})--->
={"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*{1;10;100;1000;10000;100000;1000000;10000000;100000000;1000000000}--->可以得到下面的值 ={1;10;100;1000;10000;100000;3000000;90000000;800000000;7000000000} 加個sum 可以得到=7893111111 與上面剛好相反

例3
SUM({"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*(10^(-{0;1;2;3;4;5;6;7;8;9})))--> =SUM({"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*({1;0.1;0.01;0.001;0.0001;0.00001;0.000001;0.0000001;0.00000001;0.000000001}))--> =SUM({1;0.1;0.01;0.001;0.0001;0.00001;0.000003;0.0000009;0.00000008;0.000000007}) =1.111113987

例4
=sum({"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*10^(-{9;8;7;6;5;4;3;2;1;0}))---> =sum({"1";"1";"1";"1";"1";"1";"3";"9";"8";"7"}*{0.000000001;0.00000001;0.0000001;0.000001;0.00001;0.0001;0.001;0.01;0.1;1}) ---> =SUM({0.000000001;0.00000001;0.0000001;0.000001;0.00001;0.0001;0.003;0.09;0.8;7})->>=7.893111111