這里，就SqlServer，DBF兩種格式的轉(zhuǎn)化問題做個總結(jié)。
一： 從dBase文件中,導(dǎo)入數(shù)據(jù)到SQL數(shù)據(jù)庫中,很簡單,直接用下面的語句:
/*===================================================================*/
--假如接受數(shù)據(jù)導(dǎo)入的表已經(jīng)存在
insert into 表 select * from
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')
--假如導(dǎo)入數(shù)據(jù)并生成表
select * into 表 from
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')
/*===================================================================*/
--假如從SQL數(shù)據(jù)庫中,導(dǎo)出數(shù)據(jù)到dBase,假如dBase文件已經(jīng)存在,就可以簡單的用:
insert into
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')
select * from 表
/*--說明:
DATABASE=c:/ c:/是dbf文件的存放目錄
'select * from [test.dbf] test.dbf是指dbf文件名
--*/
二 假如dBase文件不存在,就需要用到下面的存儲過程了.
/*--數(shù)據(jù)導(dǎo)出dBase
導(dǎo)出表中的數(shù)據(jù)到dBase,假如文件不存在,將自動創(chuàng)建文件
基于通用性考慮,僅支持導(dǎo)出標(biāo)準(zhǔn)數(shù)據(jù)類型
--*/
/*--調(diào)用示例
--導(dǎo)出dBase
p_eXPorttb @tbname='地區(qū)資料',@path='c:/',@over=0
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_exporttb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_exporttb]
GO
create proc p_exporttb
@tbname sysname, --要導(dǎo)出的表名
@path nvarchar(1000), --文件存放目錄
@fname nvarchar(250)='', --文件名,默認(rèn)為表名
@over bit=0 --是否覆蓋已經(jīng)存在的文件,假如不覆蓋,則直接追加
as
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)
--參數(shù)檢測
if isnull(@fname,'')='' set @fname=@tbname+'.dbf'
--檢查文件是否已經(jīng)存在
if right(@path,1)<>'/' set @path=@path+'/'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
if @over=1
begin
set @sql='del '+@sql
exec master..xp_cmdshell @sql,no_output
end
else
set @over=0
else
set @over=1
--數(shù)據(jù)庫創(chuàng)建語句
set @sql=@path+@fname
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'
+';HDR=NO;DATABASE='+@path+'"'
--連接數(shù)據(jù)庫
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr
exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr
--創(chuàng)建表的SQL
select @sql='',@fdlist=''
select @fdlist=@fdlist+','+a.name
,@sql=@sql+',['+a.name+'] '
+case when b.name in('char','nchar','varchar','nvarchar') then
'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
when b.name in('tynyint','int','bigint','tinyint') then 'int'
when b.name in('smalldatetime','datetime') then 'datetime'
when b.name in('money','smallmoney') then 'money'
else b.name end
FROM syscolumns a left join systypes b on a.xtype=b.xusertype
where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
and object_id(@tbname)=id
select @sql='create table ['+@fname
+']('+substring(@sql,2,8000)+')'
,@fdlist=substring(@fdlist,2,8000)
if @over=1
begin
exec @err=sp_oamethod @obj,'execute',@out out,@sql
if @err<>0 goto lberr
end
exec @err=sp_oadestroy @obj
set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='
+@path+''',''select * from ['+@fname+']'')'
--導(dǎo)入數(shù)據(jù)
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from '+@tbname)
return
lberr:
exec sp_oageterrorinfo 0,@src out,@desc out
lbexit:
select cast(@err as varbinary(4)) as 錯誤號
,@src as 錯誤源,@desc as 錯誤描述
select @sql,@constr,@fdlist
go
