隨著數據庫中存儲的數據的增多，滿足用戶查詢條件的數據也隨之增加。而用戶一般不可能一次性看完所有的數據， 很多時候也不需要看完所有數據。在這種情況下，分頁返回用戶查詢的數據就顯得相當的重要。分頁返回用戶數據有如下好處：
1、減少服務器磁盤系統地讀取壓力
2、減少網絡流量，減輕網絡壓力
3、減輕客戶端顯示數據的壓力
4、提高處理效率。
      一般而言，分頁處理分為兩種：應用程序中的分頁處理和數據庫中的分頁處理。目前大多數的應用都是在應用程序中借助支持數據分頁處理的數據庫訪問組件（如DataGrid控件）實現分頁處理。實際上，在數據庫中實現分頁處理，可以從源頭減少數據處理量，效果往往可能跟明顯。本文主要討論數據庫的分頁問題。
      常規的取第n頁數據方法為： Select top PageSize * from TableA where PRimary_Key not in (select top (n-1)*PageSize Primary_Key from TableA )。
      對于應用程序而言，所做的就是在生成分頁處理的T-SQL語句前先計算好各數字， 對于數據庫而言，應該采用動態的T-SQL語句。
 以下是使用上述原理實現的通用分頁處理存儲過程：

create proc up_PageView
(
    @tableName sysname,
    @colKey    nvarchar(100),
    @pageCurrent int = 1,
    @pageSize int = 10,
    @colShow nvarchar(4000) = '',
    @colOrder nvarchar(200) = '',
    @where nvarchar(2000) = '',
    @pageCount int output
)
as
begin
    if object_id(@tableName) is null
    begin
    raiserror('the table is not existing!', 16,1)
    return
    end
    if  isnull(@colShow, '') = ''
        set @colShow  = '*'
    if isnull(@colOrder,'') = ''
        set @colOrder = ''
    else
        set @colOrder = 'order by ' + @colOrder
    if isnull(@where, '') = ''
        set @where = ''
    else
        set @where = 'where '+ @where
    declare @sql nvarchar(4000)
    if @pageCount is null
        begin
        set @sql = 'select @pageCount = count(*) from ' + @tableName + ' ' + @where
        Exec sp_executesql @sql, '@pageCount int output', @pageCount output
        set @pageCount = (@pageCount + @pageSize -1)/@pageSize
        end
    if @pageCurrent = 1
        set @sql = 'select top' +' ' + convert(nvarchar(10), @pageSize) + ' '
                + @colshow + ' ' + 'from ' + @tableName + ' ' + @where + ' ' + @colOrder
    else
        begin
        set @sql = 'select top' +' ' + convert(nvarchar(10), @pageSize) + ' '
                + @colshow + ' ' + 'from ' + @tableName + ' ' + @where
        set @sql = @sql + ' ' + 'and '+ @colKey +' not in ( '
                + 'select top' +' ' + convert(nvarchar(10), (@pageCurrent - 1) * @pageSize) + ' '
                + @colKey + ' ' + 'from ' + @tableName + ' ' + @where  + ' )'
        set @sql = @sql + ' ' + @colOrder
        end
    --execute the dynamic query
    exec (@sql)
end

         這種方法的缺點是為了排除該頁以前的頁， 必須使用top n取大量的數據并緩存起來，在關聯元表查詢出最終結果，這樣做的效率比較低。通常情況下， 我們都是對單主健（使用單個字段定位紀錄）的表進行分頁查詢。因此，如果能使用一個字符串變量紀錄指定頁的所有主健，在使用in子句配合紀錄的指定頁主健就可以查詢出最終的結果來。下面是改進的存儲過程：

 create proc up_PageView
(
    @tableName sysname,
    @colKey    nvarchar(100),
    @pageCurrent int = 1,
    @pageSize int = 10,
    @colShow nvarchar(4000) = '',
    @colOrder nvarchar(200) = '',
    @where nvarchar(2000) = '',
    @pageCount int output
)
as
begin
    if object_id(@tableName) is null
    begin
    raiserror('the table is not existing!', 16,1)
    return
    end
    if  isnull(@colShow, '') = ''
        set @colShow  = '*'
    if isnull(@colOrder,'') = ''
        set @colOrder = ''
    else
        set @colOrder = 'order by ' + @colOrder
    if isnull(@where, '') = ''
        set @where = ''
    else
        set @where = 'where '+ @where
    declare @sql nvarchar(4000)
    if @pageCount is null
        begin
        set @sql = 'select @pageCount = count(*) from ' + @tableName + ' ' + @where
        Exec sp_executesql @sql, '@pageCount int output', @pageCount output
        set @pageCount = (@pageCount + @pageSize -1)/@pageSize -- get total pages
        end
    if @pageCurrent = 1
        begin
        set @sql = N'select top' +N' ' + convert(nvarchar(10), @pageSize) + N' '
                + @colshow + N' ' + N'from ' + @tableName + N' ' + @where + N' ' + @colOrder
        exec (@sql)
        end
    else
        begin
        declare @topN int, @topN1 int
--        set @topN = @pageSize
--        set @topN1 = @pageCurrent * @pageSize
        set @pageCurrent = @pageCurrent * @pageSize
        set @sql = N'select @n = @n - 1, @s = case when @n < ' + convert(nvarchar(10), @pageSize) +
                    N' then @s + '','' + quotename(@colKey, N'''''''') ' + N'else ''''' + N' end '
                    + N' from '+ @tableName + N' ' + @where
        --make query effect only @pageCurrent records
        --Query only top @pageCurrent * @pageSize
        set rowcount @pageCurrent
        exec sp_executesql @sql, '@n int, @s nvarchar(max) output', @pageCurrent, @sql output
        set rowcount 0 --recover to default config
        set @sql = stuff(@sql, 1, 1, N'') -- remove the first ','
        --exec the query
        Exec (N'select ' + @colShow + N' ' + 'from' + N' ' + @tableName + N' ' 
                + N'where ' + @colKey + N' in (' + @sql + ')' + @colOrder)
        end
end
go

         另外， sql server 2005 增加了一些新的功能如取得排名或順序的函數（Rank(), Dense_Rank(), Row_Number()）, 利用這些新的功能也能進行分頁處理，下面以sql server 2005 自帶的數據庫AdventureWorks為例結合Row_Number() 實現分頁處理：
 

create proc up_GetPagen
(
    @pageSize int,
    @pageCurrent int
)
as
begin
    select * from
    (select ROW_NUMBER() over(ORDER BY productid) RowNum, * from production.product )OrderData
    where RowNum between (@pageCurrent - 1)*@pageSize + 1 and @pageCurrent * @pageSize
    order by productid
end

      不盡如此，這種新功能有許多妙用， 如可以取班級排名前N名或第n名到第m名的學生等等，這類問題將會在我以后的文章中進行討論！
這是我的第一篇博客， 呵呵，處來砸到，討論的問題希望對大家有所幫助，另外，如有疑難或錯誤之處，敬請指出！
http://www.cnblogs.com/alanding/archive/2007/02/02/638197.html