asp 讀取 utf-8格式文檔并生成utf-8格式文檔的亂碼問(wèn)題

2024-05-04 10:57:56

字體：大中小

供稿：網(wǎng)友

今天在對(duì)搜索吧的程序進(jìn)行utf-8修正時(shí)，發(fā)現(xiàn)生成的utf-8格式文檔存在著亂碼，原來(lái)文件

create_html.asp代碼如下：

復(fù)制代碼代碼如下:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<%
set objrs=server.createObject("Scripting.FileSystemObject")
conn=server.mappath("example.xml")
set Stream=objrs.opentextfile(conn,1,true,-2)
content=stream.readall
Response.Write(content)
stream.close
%>

這段代碼要實(shí)現(xiàn)的功能是：從example.xml(utf-8格式)中讀取文字包括中文，然后輸出，但是每次輸出卻都是亂碼，這個(gè)問(wèn)題著實(shí)困擾了我很久，后來(lái)還是在經(jīng)典論壇“小韓”“蕭蕭小雨 ”的幫助下解決了，真是感謝他們了。

或許我一開(kāi)始就是錯(cuò)誤的，現(xiàn)在正確的代碼修改后如下，用了“蕭蕭小雨”給的代碼，包括了用讀取的內(nèi)容生成新的utf-8格式文檔。詳細(xì)代碼如下：

復(fù)制代碼代碼如下:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<% Response.CodePage=65001%>
<% Response.Charset="UTF-8" %>
<%
'申明變量
dim read_path,write_paht,content
'----讀取文件內(nèi)容------------------------
Function ReadTextFile(filePath,CharSet)
       dim stm
       set stm=Server.CreateObject("adodb.stream")
       stm.Type=1 'adTypeBinary，按二進(jìn)制數(shù)據(jù)讀入
       stm.Mode=3 'adModeReadWrite ,這里只能用3用其他會(huì)出錯(cuò)
       stm.Open
       stm.LoadFromFile filePath
       stm.Position=0 '把指針移回起點(diǎn)
       stm.Type=2 '文本數(shù)據(jù)
       stm.Charset=CharSet
       ReadTextFile = stm.ReadText
       stm.Close
       set stm=nothing
End Function

'----寫入文件------------------------
Sub WriteTextFile(filePath,fileContent,CharSet)
       dim stm
       set stm=Server.CreateObject("adodb.stream")
       stm.Type=2 'adTypeText，文本數(shù)據(jù)
       stm.Mode=3 'adModeReadWrite,讀取寫入，此參數(shù)用2則報(bào)錯(cuò)
       stm.Charset=CharSet
       stm.Open
       stm.WriteText fileContent
       stm.SaveToFile filePath,2 'adSaveCreateOverWrite，文件存在則覆蓋
       stm.Flush
       stm.Close
       set stm=nothing
End Sub
'要讀取的文件路徑
read_path = Server.MapPath("example.xml")
'要寫入的文件路徑
write_path = Server.MapPath("example.asp")
'讀取的文件內(nèi)容
content = ReadTextFile(read_path,"utf-8")
'輸出讀取的文件
Response.Write(content)
'開(kāi)始寫入
call WriteTextFile(write_path,content,"utf-8")
%>

上一篇：去除HTML代碼中所有標(biāo)簽的兩種方法

下一篇：asp下返回以千分位顯示數(shù)字格式化的數(shù)值

發(fā)表評(píng)論

共有條評(píng)論