有声读物,斗破苍穹续集,天域苍穹

23.17.1.問題
我想讓應用程序運行在后臺，不需要主界面。
23.17.2.解決辦法
在<mx:WindowedApplication>根標簽和描述文件里設置應用程序的可見性為false，使用DockIcon和SystemTrayIcon類，添加自定義程序圖標。
23.17.3.討論
是可以創建沒有主界面的應用程序，且運行在后臺。這些應用程序出現在系統托盤或停靠欄里。Mac OS X 和Windows操作系統都支持應用程序圖標，只是規定有些差別。因此AIR 針對不同操作系統提供圖標顯示類。DockIcon類是運行在Mac OS X系統下而SystemTrayIcon類是在Windows下。要檢測哪一個圖標被操作系統所支持，你可以使用NativeApplication 類的supportsDockIcon 和supportsSystemTrayIcon屬性。

DockIcon 和SystemTrayIcon 類都是繼承自flash.desktop.InteractiveIcon 抽象基類。

NativeApplication實例的icon屬性是指向操作系統支持的應用程序圖標類引用。你可以賦值圖形給icon的bitmaps屬性。Bitmaps數組里的元素都是BitmapData對象，其大小是操作系統所規定的大小。如果bitmaps屬性為空，則Mac OS X下默認的圖標會被使用而Windows系統下不會顯示圖標在系統托盤上。

除了可以添加自定義應用程序圖標外，你還可以添加當用戶點擊圖標時顯示的本地的上下文菜單。在上下文菜單上，可以監聽選擇項和運行相應的命令。下面的例子將運行在系統托盤或停靠欄上，并提供一個命令用于關閉程序：

-XML

<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical"
visible="false" windowComplete="completeHandler();">
<mx:Script>
<![CDATA[
[Embed(source='assets/AIRApp_16.png')]
private var icon16:Class;
[Embed(source='assets/AIRApp_32.png')]
private var icon32:Class;
[Embed(source='assets/AIRApp_48.png')]
private var icon48:Class;
[Embed(source='assets/AIRApp_128.png')]
private var icon128:Class;
private function completeHandler():void {
var shellMenu:NativeMenu = createShellMenu();
var icon:InteractiveIcon = NativeApplication.nativeApplication.icon;
if ( NativeApplication.supportsDockIcon ) {
( icon as DockIcon ).menu = shellMenu;
}
else
{
( icon as SystemTrayIcon ).menu = shellMenu;
( icon as SystemTrayIcon ).tooltip = "My App" ;
}
var bitmaps:Array = [new icon16(), new icon32(), new icon48(), new icon128()];
icon.bitmaps = bitmaps;
}
private function createShellMenu():NativeMenu {
var menu:NativeMenu = new NativeMenu();
var quitCmd:NativeMenuItem = new NativeMenuItem( "Quit");
quitCmd.addEventListener(Event.SELECT,quitHandler );
menu.addItem( quitCmd );
return menu;
}
private function quitHandler( evt:Event ):void {
NativeApplication.nativeApplication.exit();
}

]]>
</mx:Script>
</mx:WindowedApplication>