23.8.瀏覽本地文件

2024-04-27 13:52:33

字體：大中小

來源：轉載

供稿：網友

23.8.1.問題
我想使用打開對話框和保存對話框用于打開和保存文件。
23.8.2.解決辦法
使用flash.filesystem.File類的browse開頭的那些方法。
23.8.3.討論
File類提供了一個對話框窗口用于打開一個或多個文件。使用File.browseForOpen方法選擇一個文件時select 事件被觸發，使用File.browseForOpenMultiple 方法選擇多個文件時selecteMutiple事件被觸發。

下面的例子打開一個對話框選擇一個特定擴展名的文件：

-ActionScript

private var file:File = new File();
private var filter:FileFilter = new FileFilter( "Text", "*.txt", "*.xml","*.html");
private function initHandler():void {
file.browseForOpen( "Open File" , [filter] );
file.addEventListener( Event.SELECT, selectHandler );
file.addEventListener( Event.CANCEL, cancelHandler );
}
private function selectHandler( evt:Event ):void {
var stream:FileStream = new FileStream();
stream.open( file, FileMode.READ );
trace( stream.readUTFBytes( stream.bytesAvailable ) );
stream.close();
}
private function cancelHandler( evt:Event ):void {
trace( "Browse cancelled.");
}

一個新的File對象被創建，File.browseForOpen方法打開一個對話框，使用FileFilter類指定特定的文件類型可被選擇，每次只能選擇一個文件。監聽select事件，在selectHandler事件處理函數中，FileStream對象把File實例放置到讀取緩沖區中。

File.browseForOpenMultiple方法打開的對話框可以一次選擇多個文件， selectMultiple事件被觸發，事件類型變成了FileListEvent：

-ActionScript

private var file:File;
private var filter:FileFilter = newFileFilter( "Text", "*.txt","*.xml,","*.html");
private function initHandler():void {
file = File.desktopDirectory;
file.browseForOpenMultiple( "Open File" , [filter] );
file.addEventListener( FileListEvent.SELECT_MULTIPLE, selectHandler );
}
private function selectHandler( evt:FileListEvent ):void {
trace ( "Selected files from: " + file.url + "/n" );
var files:Array = evt.files;
for ( var i:int = 0; i < files.length; i++ ) {
trace ( ( files[i] as File ).name + "/n" );
}
}

在這個例子中，打開文件對話框被打開并指向用戶的桌面目錄，選擇文件后，selectHandler 發被調用并打印出被選擇的文件名。

File類也支持保存對話框，在保存對話框里，用戶選擇一個目錄，輸入文件名保存文件。下面的例子打開保存文件對話框，寫入文本Hello World到目標文件：

-ActionScript

private var file:File;
private function initHandler():void {
file = File.desktopDirectory;
file.browseForSave( "Save As" );
file.addEventListener( Event.SELECT, selectHandler );
}
private function selectHandler( evt:Event ):void {
var stream:FileStream = new FileStream();
stream.open( evt.target as File, FileMode.WRITE );
stream.writeUTFBytes( "Hello World." );
stream.close();
}