package oreilly.cookbook
{
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.events.TextEvent;
import flash.text.TextField;
import mx.core.UIComponent;
public class TextDropShadow extends UIComponent
{
private var _useShadow:Boolean = false;
private var _shadowHolder:Bitmap;
private var _bitmapData:BitmapData;
private var _textField:TextField;
//這里，位圖已經創建而且部署到了父組件的一個偏移點，來模擬一個陰影:
public function TextDropShadow()
{
super();
_shadowHolder = new Bitmap();
addChild(_shadowHolder);
_shadowHolder.x = 5;
_shadowHolder.y = 5;
_textField = new TextField();
_textField.type = "input";
_textField.addEventListener(TextEvent.TEXT_INPUT,
inputListener);
addChild(_textField);
}
//updateDisplayList 方法是一個覆寫函數，用來繪出TextField 及其相關所有可視信息，包括文本和位圖。
override protected function
updateDisplayList(unscaledWidth:Number,
unscaledHeight:Number):void
{
super.updateDisplayList(unscaledWidth, unscaledHeight);
if(_useShadow)
{
_bitmapData = new BitmapData(_textField.width,
_textField.height, true);
_bitmapData.draw(_textField);
_shadowHolder.bitmapData = _bitmapData;
_shadowHolder.alpha = 0.7;
}
}
private function inputListener(event:TextEvent):void
{
invalidateDisplayList();
}
public function set useShadow(value:Boolean):void
{
_useShadow = value;
}
public function get useShadow():Boolean
{
return _useShadow;
}
}
}