a.txt：
代碼:
aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九
輸出如下：
代碼:
abcdefghi
ABCDEFGHI
123456789
一二三四五六七八九
唯一要求，老手略過，留給新手做練習，不能直接echo。
請先發(fā)現(xiàn)其中的規(guī)律。
其他，生成臨時文件、代碼超過一頁都不重要，正確輸出即可。
523066680：
代碼如下:
@echo off
setlocal enabledelayedexpansion
set a=-1
for /f "tokens=*" %%a in ('type 1.x') do set hang=%%a
:a
set /a a+=1
set /a b=%a%
:b
set hang%a%=!hang%a%!!hang:~%b%,1!
set /a b=%b%+4
if not "!hang:~%b%,1!"=="" goto :b
echo,!hang%a%!
if %a% leq 2 goto :a
pause
這個思路很直接，沒啥特別之處，就是設
第一行為1,5,9,13,……位上的
第二行為2,6,10,14……位上的
隨風：
代碼如下:
@echo off&setlocal EnableDelayedExpansion
set "str=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%a in (0 1 35) do (
set /a n+=1
call set .!n!=%%.!n!%%!str:~%%a,1!
set /a n=n%%4
)
for /f "tokens=2 delims==" %%a in ('set .') do echo %%a
pause>nul
terse：
代碼如下:
@echo off&setlocal EnableDelayedExpansion
set "str=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%i in (0 1 3) do for /l %%j in (%%i 4 35) do set %%i=!%%i!!str:~%%j,1!
for /l %%i in (0 1 3) do echo !%%i!
pause>nul
netbenton：
代碼如下:
@echo off&setlocal ENABLEDELAYEDEXPANSION
set "x=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%a in (0,1,3) do ((for /l %%b in (%%a,4,35) do set/p=!x:~%%b,1!<nul)&echo.)
pause
