利用Jmail.Message發送郵件

2019-11-18 20:16:22

字體：大中小

來源：轉載

供稿：網友

該段代碼涉及到jmail v4.3的大部分常用方法。
包括郵件基本信息、身份驗證、附件等。無需很多的修改就可以使用，也可以改成函數或過程。

<%
Dim JMail, contentId
Set JMail = Server.CreateObject("JMail.Message")

JMail.Charset = "gb2312" ' 郵件字符集，默認為"US-ASCII"
' JMail.ISOEncodeHeaders = False ' 是否進行ISO編碼，默認為True

' 發送者信息（可用變量方式賦值）
JMail.From = "jiaz@21cn.com" ' 發送者地址
JMail.FromName = "D.J." ' 發送者姓名
JMail.Subject = "您在炫網資訊的歌詞快遞（請將編碼設為簡體中文(gb2312)）" ' 郵件主題

' 身份驗證
JMail.MailServerUserName = "user" ' 身份驗證的用戶名
JMail.MailServerPassWord = "password" ' 身份驗證的密碼

' 設置優先級，范圍從1到5，越大的優先級越高，3為普通
JMail.PRiority = 3

JMail.AddHeader "Originating-ip", Request.ServerVariables("REMOTE_ADDR")

' 加入一個收件人【變量email：收件人地址】可以同一語句重復加入多個
JMail.AddRecipient(email)

' 加入附件【變量filename：附件文件的絕對地址，確保用戶IUSR_????有訪問的權限】
' 【參數設置是(True)否(False)為Inline方式】
contentId = JMail.AddAttachment (filename, True)

' 郵件主體（HTML(注意信件內鏈接附件的方式)）
JMail.HTMLBody = "<html><head><META content=zh-cn http-equiv=Content-Language><meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312""><style type=text/CSS>A:link { FONT-SIZE: 9pt; TEXT-DECORATION: none; color: #000000}A:visited {FONT-SIZE: 9pt; TEXT-DECORATION: none; color: #666666}A:hover {COLOR: #ff6600; FONT-SIZE: 9pt; TEXT-DECORATION: underline}BODY {FONT-SIZE: 9pt} --></style></head><body bgcolor=""#FFFFFF"" text=""#666666"" leftmargin=""0"" topmargin=""30"" link=""#FF9900""><center>點擊這里<a href=' cid:" & contentId & "' >[附件文件]</a>將文件保存</center></body></html>"

' 郵件主體（文本部分）
JMail.Body = "我們的郵件采用了HTML格式，但是您的郵件查看軟件可能不支持。您可以訪問以下地址來查看：http://music.liuxuan.com"

' 發送【調用格式：objJMail.Send([username:password@]SMTPServerAddress[:Port])】
JMail.Send("user:password@smtp.21cn.com")

' 關閉并清除對象
JMail.Close()
Set JMail = Nothing
%>

上一篇：asp中通過getrows實現數據庫記錄分頁的一段代碼

下一篇：加密處理使密碼更安全